COMMENT ⊗   VALID 00002 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002		TITLE PLOT
C00006 ENDMK
C⊗;
	TITLE PLOT
	INTERNAL PLOT,JZERO,IFIX,FLOAT,EXCH,SWITCH
	EXTERNAL FASTOU,FINFIL,EXIT,PUTFIL,OUTF,PLT

IFIX:	0
	KIFIX 0,@(16)
	JRA 16,1(16)
FLOAT:	0
	FLTR 0,@(16)
	JRA 16,1(16)

SWITCH:	0
	SKIPN PLT+4
	JRST S1
	MOVE PLT+=11
	SUBM PLT+=18
S1:	SKIPN PLT+5
	JRA 16,(16)
	MOVE PLT+=12
	SUBM PLT+=19
	JRA 16,(16)

JZERO:	0
	SETZM PLT+=20
	SETZM PLT+=21
	JRA 16,(16)

EXCH:	0
	MOVE 0,@(16)
	EXCH 0,@1(16)
	MOVEM 0,@(16)
	JRA 16,2(16)

LX:	0
N:	BLOCK =512
PLOT:	0		;SUBROUTINE PLOT(I,J,K)
	SKIPLE OUTF	;IF(JJ.GT.0)GO TO FINISH IT.
	JRST PL1
	SETO  4,		;COMMON /OUTF/JJ
	CAMN	4,OUTF		;DIMENSION N(148)
	JRST	PL4		;IF(JJ.EQ.-1)GO TO 4
	MOVNM  4,LX		;L=1
	MOVEI	4,=127		;N(1)=127
	MOVEM	4,N
;;	MOVE	4,[ASCIZ/" "/]		;IF(JJ.EQ.' ')JJ='PLT'
;;	CAME	4,OUTF
;;	JRST	PLB
;;	MOVE	4,[ASCIZ/"PLT"/]
;;	MOVEM	4,OUTF
PLB:	JSA	16,PUTFIL	;CALL PUTFIL(JJ)
	JUMP	[ASCIZ/PLT  /]
	SETZM 	INV
	SETOM	OUTF		;JJ=-1
PL4:	MOVE	5,@2(16)	;4	IF(K.EQ.99)GO TO 1
	CAIN	5,=99
	JRST	PL1
	CAIE	5,3
	JRST	PL5
	SKIPE	INV#	;PUT THIS IN SAME PLACE IF 2 INVIS. IN A ROW.
	JRST	PL6
	SETOM 	INV
	SKIPA
PL5:	SETZM	INV
	AOS	7,LX		;L=L+1
PL6:	CAIL	7,=129
	JRST	[	CAIL 7,=257
			JRST TOP
			CAIE 7,=129
			JRST NOWD
		  WWD:	MOVEI 4,=127
			MOVEM 4,N-1(7)		;N(L)=127
			AOS LX
			JRST NOWD
		  TOP:	CAIL 7,=385
			JRST TOP2
		  	CAIE 7,=257
			JRST NOWD
			JRST WWD
		  TOP2:	CAIN 7,=385
			JRST WWD
			JRST NOWD]
			
NOWD:	MOVEI	7,N
	ADD	7,LX		;CALL PAC(N(L),I)[SEE MSFAI.FAI]
	HRRZ	4,2(16)
	HRR	5,@4
	LSHC	5,-10
	HRRZ	4,1(16)
	HRR	5,@4
	LSHC	5,-16
	MOVE 4,@(16)		;X=X-831
	SKIPE  OUTF+1	;DO THIS FOR XGP ONLY. SET FLAG IN MANFRD
	SUBI 4,=831	;FOR XGP, FLAG=-1; FOR CALCOMP, FLAG=0 
;	HRRZ	4,(16)
	HRR 5,4
;	HRR	5,@4
	LSHC	5,-16
	MOVEM	6,-1(7)

	MOVE	7,LX
	CAIGE	7,=512	;3	IF(L.LT.512)RETURN
	JRA	16,3(16)
	JSA	16,FASTOU	;2	CALL FASTOU(N,512)
	JUMP	N
	JUMP	[=512]
	MOVEI	7,1		;L=1
	MOVEM	7,LX
	JRA	16,3(16)	;RETURN
PL1:	MOVE 4,LX
	IDIVI 4,=128		;JJJ=L/128
	IMULI 4,=128		;JJJJ=JJJ*128
	MOVE 7,4
	MOVEM 5,N(7)		;FOUND LAST WDCNT.
	ADDI 4,=128		; END OF NEXT LOOP
	MOVE 5,LX
	MOVE	7,N-1(5)	;J=N(L)
	AOJ 5,			; (L=L+1)
PL100:	MOVEM	7,N-1(5)	;DO 100 JJ=L,JXXX  (AC4)
				;100	N(JJ)=J
	CAMGE	5,4
	AOJA	5,PL100
	JSA	16,FASTOU	;CALL FASTOU(N,512)
	JUMP	N
	JUMP	4
	JSA	16,FINFIL	;CALL FINFIL
	SETZM	OUTF		;JJ=0
	JSA	16,EXIT		;CALL EXIT

	END